Mirc Oyun yukle tetris

Mayıs 31st, 2009 by admin

Bu yazımızda Mirc ‘ e tetris yükleyip chat yaparken nasil oyun oynayacaksınız bunu anlatacagız.

Öncelikle bilgisayarınızda remotesi açık bir mirc yüklemeniz lazım Mirc indirmek için

Mirci indirdikten sonra Mircimiz acıkken ALT+R yapıyoruz dosya ve yeni sekmesini işaretliyerek yeni bir remote sayfası açıyorsunuz.

Daha Sonra Aşagıdakı Kodları burya yapıştırıyorsunuz.!

on *:load:{
if ($version < 6.03) { echo -a Version de mIRC imcompatible. Nécessite au moins mIRC v6.03 | .unload $+(”,$script,”) }
else echo -a Tetris par DixrouE chargé avec succès! Pour jouer, /tetris
}
menu status,menubar,channel {
Tetris:tetris
}
alias tetris {
if ($window(@tetris)) window -a @tetris
else {
hmake tetris 2 | window -akpCB @Tetris -1 -1 343 345
drawfill -r @tetris 16777215 16777215 0 0
drawrect -r @tetris 0 1 9 9 222 302
drawrect -r @tetris 0 1 240 10 85 30
drawrect -r @tetris 16777215 1 245 10 35 10
drawtext -r @tetris 0 Tahoma 10 250 4 Points
drawrect -r @tetris 0 1 240 50 85 30
drawrect -r @tetris 16777215 1 245 50 39 10
drawtext -r @tetris 0 Tahoma 10 250 44 Niveau
drawrect -r @tetris 0 1 240 90 85 30
drawrect -r @tetris 16777215 1 245 90 37 10
drawtext -r @tetris 0 Tahoma 10 250 84 Lignes
drawrect -r @tetris 0 1 240 130 85 97
drawrect -r @tetris 16777215 1 245 130 48 10
drawtext -r @tetris 0 Tahoma 10 250 124 Prochain
drawtext -or @tetris 0 Verdana 15 255 240 Pause
ht points 0 | ht niveau 1 | ht lignes 0 | tetris.points
tetris.blocs p | tetris.makeblocs
}
}
menu @tetris {
uclick {
if ($inrect($mouse.x,$mouse.y,255,240,50,18)) && (!$ht(go)) {
if ($timer(tetris)) { var %a = 6579300 | .timertetris off }
else { var %a = 0 | .timertetris -m 0 750 tetris.draw }
drawtext -or @tetris %a Verdana 15 255 240 Pause
}
}
}
on *:close:@tetris:{ hfree tetris | .timertetris off }
alias ht { if ($isid) return $hget(tetris,$1) | else hadd tetris $1- }
alias -l tetris.blocs {
var %a = 10
while (%a < 220) {
if ($ht($+(%a,.10))) {
.timertetris off | ht go 1
drawtext -ro @tetris 0 Verdana 20 50 100 Game Over!
halt
}
inc %a 20
}
var %a = $r(1,7) | ht rotate 0 | ht $+($1,bloc) %a
if (%a == 1) {
ht $+($1,bloc1.x) 90 | ht $+($1,bloc1.y) -30 | ht $+($1,bloc2.x) 110 | ht $+($1,bloc2.y) -30
ht $+($1,bloc3.x) 90 | ht $+($1,bloc3.y) -10 | ht $+($1,bloc4.x) 110 | ht $+($1,bloc4.y) -10
ht $+($1,couleur) 1338900
}
if (%a == 2) {
ht $+($1,bloc1.x) 110 | ht $+($1,bloc1.y) -70 | ht $+($1,bloc2.x) 110 | ht $+($1,bloc2.y) -50
ht $+($1,bloc3.x) 110 | ht $+($1,bloc3.y) -30 | ht $+($1,bloc4.x) 110 | ht $+($1,bloc4.y) -10
ht $+($1,couleur) 660695
}
if (%a == 3) {
ht $+($1,bloc1.x) 90 | ht $+($1,bloc1.y) -50 | ht $+($1,bloc2.x) 90 | ht $+($1,bloc2.y) -30
ht $+($1,bloc3.x) 90 | ht $+($1,bloc3.y) -10 | ht $+($1,bloc4.x) 110 | ht $+($1,bloc4.y) -10
ht $+($1,couleur) 4320245
}
if (%a == 4) {
ht $+($1,bloc1.x) 110 | ht $+($1,bloc1.y) -50 | ht $+($1,bloc2.x) 110 | ht $+($1,bloc2.y) -30
ht $+($1,bloc3.x) 110 | ht $+($1,bloc3.y) -10 | ht $+($1,bloc4.x) 90 | ht $+($1,bloc4.y) -10
ht $+($1,couleur) 8545310
}
if (%a == 5) {
ht $+($1,bloc1.x) 90 | ht $+($1,bloc1.y) -50 | ht $+($1,bloc2.x) 90 | ht $+($1,bloc2.y) -30
ht $+($1,bloc3.x) 110 | ht $+($1,bloc3.y) -30 | ht $+($1,bloc4.x) 110 | ht $+($1,bloc4.y) -10
ht $+($1,couleur) 10855845
}
if (%a == 6) {
ht $+($1,bloc1.x) 110 | ht $+($1,bloc1.y) -50 | ht $+($1,bloc2.x) 110 | ht $+($1,bloc2.y) -30
ht $+($1,bloc3.x) 90 | ht $+($1,bloc3.y) -30 | ht $+($1,bloc4.x) 90 | ht $+($1,bloc4.y) -10
ht $+($1,couleur) 692600
}
if (%a == 7) {
ht $+($1,bloc1.x) 70 | ht $+($1,bloc1.y) -30 | ht $+($1,bloc2.x) 90 | ht $+($1,bloc2.y) -30
ht $+($1,bloc3.x) 110 | ht $+($1,bloc3.y) -30 | ht $+($1,bloc4.x) 90 | ht $+($1,bloc4.y) -10
ht $+($1,couleur) 3947580
}
drawrect -fr @tetris 16777215 1 241 135 83 91
if ($tetris.smaller(p) == $calc($tetris.bigger(p) - 20)) var %b = 170
elseif ($calc($tetris.smaller(p) + $tetris.bigger(p)) == 180) var %b = 180
else var %b = 160
tetris.drawblocs $ht(pcouleur) $calc($ht(pbloc1.x) + %b) $calc($ht(pbloc1.y) + 210)
tetris.drawblocs $ht(pcouleur) $calc($ht(pbloc2.x) + %b) $calc($ht(pbloc2.y) + 210)
tetris.drawblocs $ht(pcouleur) $calc($ht(pbloc3.x) + %b) $calc($ht(pbloc3.y) + 210)
tetris.drawblocs $ht(pcouleur) $calc($ht(pbloc4.x) + %b) $calc($ht(pbloc4.y) + 210)
}
alias -l tetris.drawblocs {
if ($4 == n) var %a = -frn | else var %a = -fr | var %b = $1, %c = $2, %d = $3 | tokenize 44 $rgb($color($1))
var %1 = $1 + 20, %2 = $2 + 20, %3 = $3 + 20, %4 = $1 - 20, %5 = $2 - 20, %6 = $3 - 20
drawrect %a @tetris %b 1 %c %d 20 20 | drawrect -r @tetris $rgb(%4,%5,%6) 1 %c %d 20 20
drawline -r @tetris $rgb(%1,%2,%3) 1 %c $calc(%d + 19) $calc(%c + 20) $calc(%d + 19)
drawline -r @tetris $rgb(%1,%2,%3) 1 $calc(%c + 19) %d $calc(%c + 19) $calc(%d + 20)
}
alias -l tetris.makeblocs {
ht bloc1.x $ht(pbloc1.x) | ht bloc1.y $ht(pbloc1.y) | ht bloc2.x $ht(pbloc2.x) | ht bloc2.y $ht(pbloc2.y)
ht bloc3.x $ht(pbloc3.x) | ht bloc3.y $ht(pbloc3.y) | ht bloc4.x $ht(pbloc4.x) | ht bloc4.y $ht(pbloc4.y)
ht couleur $ht(pcouleur) | ht bloc $ht(pbloc) | tetris.blocs p
}
alias -l tetris.draw {
if ($ht($+($ht(bloc1.x),.,$calc($ht(bloc1.y) + 20)))) var %b = 1
if ($ht($+($ht(bloc2.x),.,$calc($ht(bloc2.y) + 20)))) var %b = 1
if ($ht($+($ht(bloc3.x),.,$calc($ht(bloc3.y) + 20)))) var %b = 1
if ($ht($+($ht(bloc4.x),.,$calc($ht(bloc4.y) + 20)))) var %b = 1
var %a = $ht(bloc1.y)
if (%a < $ht(bloc2.y)) var %a = $ht(bloc2.y)
if (%a < $ht(bloc3.y)) var %a = $ht(bloc3.y)
if (%a < $ht(bloc4.y)) var %a = $ht(bloc4.y)
if (%a > 280) var %b = 1
if (%b) {
ht $+($ht(bloc1.x),.,$ht(bloc1.y)) $ht(couleur)
ht $+($ht(bloc2.x),.,$ht(bloc2.y)) $ht(couleur)
ht $+($ht(bloc3.x),.,$ht(bloc3.y)) $ht(couleur)
ht $+($ht(bloc4.x),.,$ht(bloc4.y)) $ht(couleur)
var %d = 10
while (%d < 300) {
var %e = 10, %f = 0
while (%e < 220) { if ($ht($+(%e,.,%d))) inc %f | inc %e 20 }
if (%f == 11) {
var %g = $calc(%d - 20)
while (%g > 10) {
var %h = 10 | while (%h < 220) { ht $+(%h,.,$calc(%g + 20)) $ht($+(%h,.,%g)) | inc %h 20 } | dec %g 20
}
drawrect -frn @tetris 16777215 1 10 10 220 300
var %i = 10
while (%i < 300) {
var %j = 10
while (%j < 220) { if ($ht($+(%j,.,%i))) tetris.drawblocs $ifmatch %j %i n | inc %j 20 } | inc %i 20
}
drawdot @tetris | hinc tetris lignes | hinc tetris points 10
if (. !isin $calc($ht(lignes) / 10)) hinc tetris niveau | tetris.points
.timertetris -m 0 $iif($calc(750 - ($ht(niveau) * 100)) > 200,$ifmatch,200) tetris.draw
}
inc %d 20
}
tetris.makeblocs
}
var %c = hinc tetris, %d = 20 20
if ($ht(bloc1.y) > 0) drawrect -fr @tetris 16777215 1 $ht(bloc1.x) $ht(bloc1.y) %d
if ($ht(bloc2.y) > 0) drawrect -fr @tetris 16777215 1 $ht(bloc2.x) $ht(bloc2.y) %d
if ($ht(bloc3.y) > 0) drawrect -fr @tetris 16777215 1 $ht(bloc3.x) $ht(bloc3.y) %d
if ($ht(bloc4.y) > 0) drawrect -fr @tetris 16777215 1 $ht(bloc4.x) $ht(bloc4.y) %d
%c bloc1.y 20 | %c bloc2.y 20 | %c bloc3.y 20 | %c bloc4.y 20
if ($ht(bloc1.y) > 0) tetris.drawblocs $ht(couleur) $ht(bloc1.x) $ht(bloc1.y)
if ($ht(bloc2.y) > 0) tetris.drawblocs $ht(couleur) $ht(bloc2.x) $ht(bloc2.y)
if ($ht(bloc3.y) > 0) tetris.drawblocs $ht(couleur) $ht(bloc3.x) $ht(bloc3.y)
if ($ht(bloc4.y) > 0) tetris.drawblocs $ht(couleur) $ht(bloc4.x) $ht(bloc4.y)
}
alias -l tetris.smaller {
var %a = $ht($+($1,bloc1.x))
if (%a > $ht($+($1,bloc2.x))) var %a = $ht($+($1,bloc2.x))
if (%a > $ht($+($1,bloc3.x))) var %a = $ht($+($1,bloc3.x))
if (%a > $ht($+($1,bloc4.x))) var %a = $ht($+($1,bloc4.x))
return %a
}
alias -l tetris.bigger {
var %a = $ht($+($1,bloc1.x))
if (%a < $ht($+($1,bloc2.x))) var %a = $ht($+($1,bloc2.x))
if (%a < $ht($+($1,bloc3.x))) var %a = $ht($+($1,bloc3.x))
if (%a < $ht($+($1,bloc4.x))) var %a = $ht($+($1,bloc4.x))
return %a
}
alias -l tetris.smaller2 {
var %a = $ht($+($1,bloc1.y))
if (%a > $ht($+($1,bloc2.y))) var %a = $ht($+($1,bloc2.y))
if (%a > $ht($+($1,bloc3.y))) var %a = $ht($+($1,bloc3.y))
if (%a > $ht($+($1,bloc4.y))) var %a = $ht($+($1,bloc4.y))
return %a
}
alias -l tetris.bigger2 {
var %a = $ht($+($1,bloc1.y))
if (%a < $ht($+($1,bloc2.y))) var %a = $ht($+($1,bloc2.y))
if (%a < $ht($+($1,bloc3.y))) var %a = $ht($+($1,bloc3.y))
if (%a < $ht($+($1,bloc4.y))) var %a = $ht($+($1,bloc4.y))
return %a
}
alias -l tetris.rotate ht $+(rbloc,$1) $calc($ht($+(bloc,$1)) + $2)
alias -l tetris.arotate { if ($2) ht $+(bloc,$1) $2 | else ht $+(bloc,$1) $ht($+(bloc,$1)) }
on *:keydown:@tetris:37,38,39,40:{
if ($timer(tetris)) {
if ($keyval == 37) && ($tetris.smaller > 20) var %z = hdec
if ($keyval == 38) {
var %w = $ht(bloc1.x) $ht(bloc1.y), %x = $ht(bloc2.x) $ht(bloc2.y)
var %y = $ht(bloc3.x) $ht(bloc3.y), %z = $ht(bloc4.x) $ht(bloc4.y)
var %a = $ht(bloc) | if ($ht(rotate) == 4) ht rotate 0 | hinc tetris rotate
var %b = $ht(rotate), %c = hinc tetris
if (%a == 2) {
if (%b == 1) || (%b == 3) {
tetris.rotate 1.x 40 | tetris.rotate 1.y 40 | tetris.rotate 2.x 20 | tetris.rotate 2.y 20
tetris.rotate 4.x -20 | tetris.rotate 4.y -20
}
else {
tetris.rotate 1.x -40 | tetris.rotate 1.y -40 | tetris.rotate 2.x -20 | tetris.rotate 2.y -20
tetris.rotate 4.x 20 | tetris.rotate 4.y 20
}
}
if (%a == 3) {
if (%b == 1) {
tetris.rotate 1.x 40 | tetris.rotate 1.y 20 | tetris.rotate 2.x 20 | tetris.rotate 2.y 0
tetris.rotate 3.x 0 | tetris.rotate 3.y -20 | tetris.rotate 4.x -20 | tetris.rotate 4.y 0
}
if (%b == 2) {
tetris.rotate 1.x -20 | tetris.rotate 1.y 60 | tetris.rotate 2.x 0 | tetris.rotate 2.y 40
tetris.rotate 3.x 20 | tetris.rotate 3.y 20 | tetris.rotate 4.x 0 | tetris.rotate 4.y 0
}
if (%b == 3) {
tetris.rotate 1.x -40 | tetris.rotate 1.y -20 | tetris.rotate 2.x -20 | tetris.rotate 2.y 0
tetris.rotate 3.x 0 | tetris.rotate 3.y 20 | tetris.rotate 4.x 20 | tetris.rotate 4.y 0
}
if (%b == 4) {
tetris.rotate 1.x 20 | tetris.rotate 1.y -40 | tetris.rotate 2.x 0 | tetris.rotate 2.y -20
tetris.rotate 3.x -20 | tetris.rotate 3.y 0 | tetris.rotate 4.x 0 | tetris.rotate 4.y 20
}
}
if (%a == 4) {
if (%b == 1) {
tetris.rotate 1.x 20 | tetris.rotate 1.y 40 | tetris.rotate 2.x 0 | tetris.rotate 2.y 20
tetris.rotate 3.x -20 | tetris.rotate 3.y 0 | tetris.rotate 4.x 0 | tetris.rotate 4.y -20
}
if (%b == 2) {
tetris.rotate 1.x -40 | tetris.rotate 1.y 20 | tetris.rotate 2.x -20 | tetris.rotate 2.y 0
tetris.rotate 3.x 0 | tetris.rotate 3.y -20 | tetris.rotate 4.x 20 | tetris.rotate 4.y 0
}
if (%b == 3) {
tetris.rotate 1.x -20 | tetris.rotate 1.y -40 | tetris.rotate 2.x 0 | tetris.rotate 2.y -20
tetris.rotate 3.x 20 | tetris.rotate 3.y 0 | tetris.rotate 4.x 0 | tetris.rotate 4.y 20
}
if (%b == 4) {
tetris.rotate 1.x 40 | tetris.rotate 1.y -20 | tetris.rotate 2.x 20 | tetris.rotate 2.y 0
tetris.rotate 3.x 0 | tetris.rotate 3.y 20 | tetris.rotate 4.x -20 | tetris.rotate 4.y 0
}
}
if (%a == 5) {
if (%b == 1) {
tetris.rotate 1.x 40 | tetris.rotate 1.y 0 | tetris.rotate 2.x 20 | tetris.rotate 2.y -20
tetris.rotate 3.x 0 | tetris.rotate 3.y 0 | tetris.rotate 4.x -20 | tetris.rotate 4.y -20
}
if (%b == 2) {
tetris.rotate 1.x 0 | tetris.rotate 1.y 20 | tetris.rotate 2.x 20 | tetris.rotate 2.y 0
tetris.rotate 3.x 0 | tetris.rotate 3.y -20 | tetris.rotate 4.x 20 | tetris.rotate 4.y -40
}
if (%b == 3) {
tetris.rotate 1.x -20 | tetris.rotate 1.y 0 | tetris.rotate 2.x 0 | tetris.rotate 2.y 20
tetris.rotate 3.x 20 | tetris.rotate 3.y 0 | tetris.rotate 4.x 40 | tetris.rotate 4.y 20
}
if (%b == 4) {
tetris.rotate 1.x 0 | tetris.rotate 1.y -20 | tetris.rotate 2.x -20 | tetris.rotate 2.y 0
tetris.rotate 3.x 0 | tetris.rotate 3.y 20 | tetris.rotate 4.x -20 | tetris.rotate 4.y 40
}
}
if (%a == 6) {
if (%b == 1) {
tetris.rotate 1.x 20 | tetris.rotate 1.y 20 | tetris.rotate 2.x 0 | tetris.rotate 2.y 0
tetris.rotate 3.x 20 | tetris.rotate 3.y -20 | tetris.rotate 4.x 0 | tetris.rotate 4.y -40
}
if (%b == 2) {
tetris.rotate 1.x -20 | tetris.rotate 1.y 0 | tetris.rotate 2.x 0 | tetris.rotate 2.y -20
tetris.rotate 3.x 20 | tetris.rotate 3.y 0 | tetris.rotate 4.x 40 | tetris.rotate 4.y -20
}
if (%b == 3) {
tetris.rotate 1.x 0 | tetris.rotate 1.y -20 | tetris.rotate 2.x 20 | tetris.rotate 2.y 0
tetris.rotate 3.x 0 | tetris.rotate 3.y 20 | tetris.rotate 4.x 20 | tetris.rotate 4.y 40
}
if (%b == 4) {
tetris.rotate 1.x 40 | tetris.rotate 1.y -20 | tetris.rotate 2.x 20 | tetris.rotate 2.y 0
tetris.rotate 3.x 0 | tetris.rotate 3.y -20 | tetris.rotate 4.x -20 | tetris.rotate 4.y 0
}
}
if (%a == 7) {
if (%b == 1) {
tetris.rotate 1.x 20 | tetris.rotate 1.y -20 | tetris.rotate 2.x 0 | tetris.rotate 2.y 0
tetris.rotate 3.x -20 | tetris.rotate 3.y 20 | tetris.rotate 4.x -20 | tetris.rotate 4.y -20
}
if (%b == 2) {
tetris.rotate 1.x 20 | tetris.rotate 1.y 20 | tetris.rotate 2.x 0 | tetris.rotate 2.y 0
tetris.rotate 3.x -20 | tetris.rotate 3.y -20 | tetris.rotate 4.x 20 | tetris.rotate 4.y -20
}
if (%b == 3) {
tetris.rotate 1.x -20 | tetris.rotate 1.y 20 | tetris.rotate 2.x 0 | tetris.rotate 2.y 0
tetris.rotate 3.x 20 | tetris.rotate 3.y -20 | tetris.rotate 4.x 20 | tetris.rotate 4.y 20
}
if (%b == 4) {
tetris.rotate 1.x -20 | tetris.rotate 1.y -20 | tetris.rotate 2.x 0 | tetris.rotate 2.y 0
tetris.rotate 3.x 20 | tetris.rotate 3.y 20 | tetris.rotate 4.x -20 | tetris.rotate 4.y 20
}
}
if ($istok(2.3.4.5.6.7,%a,46)) {
if (!$ht($+($ht(rbloc1.x),.,$ht(rbloc1.y)))) && (!$ht($+($ht(rbloc2.x),.,$ht(rbloc2.y)))) {
if (!$ht($+($ht(rbloc3.x),.,$ht(rbloc3.y)))) && (!$ht($+($ht(rbloc4.x),.,$ht(rbloc4.y)))) {
if ($tetris.smaller > 10) && ($tetris.bigger(r) < 221) && ($tetris.smaller2(r) > 10) && ($tetris.bigger2(r) < 301) {
tetris.arotate 1.x $ht(rbloc1.x) | tetris.arotate 1.y $ht(rbloc1.y)
tetris.arotate 2.x $ht(rbloc2.x) | tetris.arotate 2.y $ht(rbloc2.y)
tetris.arotate 3.x $ht(rbloc3.x) | tetris.arotate 3.y $ht(rbloc3.y)
tetris.arotate 4.x $ht(rbloc4.x) | tetris.arotate 4.y $ht(rbloc4.y)
drawrect -fr @tetris 16777215 1 %w 20 20 | drawrect -fr @tetris 16777215 1 %x 20 20
drawrect -fr @tetris 16777215 1 %y 20 20 | drawrect -fr @tetris 16777215 1 %z 20 20
tetris.drawblocs $ht(couleur) $ht(bloc1.x) $ht(bloc1.y)
tetris.drawblocs $ht(couleur) $ht(bloc2.x) $ht(bloc2.y)
tetris.drawblocs $ht(couleur) $ht(bloc3.x) $ht(bloc3.y)
tetris.drawblocs $ht(couleur) $ht(bloc4.x) $ht(bloc4.y)
drawrect -r @tetris 0 1 9 9 222 302 | tetris.rdel
}
else tetris.del
}
else tetris.del
}
else tetris.del
}
else tetris.del
}
if ($keyval == 39) && ($tetris.bigger < 200) var %z = hinc
if ($keyval == 40) tetris.draw
if (%z) {
var %a = %z tetris
if (%z == hdec) var %b = - | else var %b = +
if ($ht($+($calc($ht(bloc1.x) %b 20),.,$ht(bloc1.y)))) var %c = 1
if ($ht($+($calc($ht(bloc2.x) %b 20),.,$ht(bloc2.y)))) var %c = 1
if ($ht($+($calc($ht(bloc3.x) %b 20),.,$ht(bloc3.y)))) var %c = 1
if ($ht($+($calc($ht(bloc4.x) %b 20),.,$ht(bloc4.y)))) var %c = 1
if (%c) return
if ($ht(bloc1.y) > 0) drawrect -fr @tetris 16777215 1 $ht(bloc1.x) $ht(bloc1.y) 20 20
if ($ht(bloc2.y) > 0) drawrect -fr @tetris 16777215 1 $ht(bloc2.x) $ht(bloc2.y) 20 20
if ($ht(bloc3.y) > 0) drawrect -fr @tetris 16777215 1 $ht(bloc3.x) $ht(bloc3.y) 20 20
if ($ht(bloc4.y) > 0) drawrect -fr @tetris 16777215 1 $ht(bloc4.x) $ht(bloc4.y) 20 20
%a bloc1.x 20 | %a bloc2.x 20 | %a bloc3.x 20 | %a bloc4.x 20
if ($ht(bloc1.y) > 0) tetris.drawblocs $ht(couleur) $ht(bloc1.x) $ht(bloc1.y)
if ($ht(bloc2.y) > 0) tetris.drawblocs $ht(couleur) $ht(bloc2.x) $ht(bloc2.y)
if ($ht(bloc3.y) > 0) tetris.drawblocs $ht(couleur) $ht(bloc3.x) $ht(bloc3.y)
if ($ht(bloc4.y) > 0) tetris.drawblocs $ht(couleur) $ht(bloc4.x) $ht(bloc4.y)
}
}
}
alias -l tetris.del { hdec tetris rotate | tetris.rdel }
alias -l tetris.rdel {
hdel tetris rbloc1.x | hdel tetris rbloc1.y | hdel tetris rbloc2.x | hdel tetris rbloc2.y
hdel tetris rbloc3.x | hdel tetris rbloc3.y | hdel tetris rbloc4.x | hdel tetris rbloc4.y
}
alias -l tetris.points {
drawrect -fr @tetris 16777215 1 242 16 80 20
drawrect -fr @tetris 16777215 1 242 56 80 20
drawrect -fr @tetris 16777215 1 242 96 80 20
drawtext -r @tetris 0 Tahoma 12 $calc(317 - $width($ht(points),Tahoma,12)) 17 $ht(points)
drawtext -r @tetris 0 Tahoma 12 $calc(317 - $width($ht(niveau),Tahoma,12)) 57 $ht(niveau)
drawtext -r @tetris 0 Tahoma 12 $calc(317 - $width($ht(lignes),Tahoma,12)) 97 $ht(lignes)
}
on *:active:*:{
if ($lactive == @tetris) .timertetris off
if ($active == @tetris) {
drawtext -or @tetris 0 Verdana 15 255 240 Pause
.timertetris -m 0 $iif($calc(750 - ($ht(niveau) * 100)) > 200,$ifmatch,200) tetris.draw
}
}

Bu kodlari ekledilten sonra tamamı tıklıyorsunuz.! mircde size bir ikaz gelir onada okey diyerek oyun kurulumunu tamamliyoruz

Mirc ‘in Status veya kanalda sağ tıkladıgınız zaman tetris eklenmiş olacak

iyi eğlenceler tetrisimizi mirce kurduk sırada eğlence var

Bu Makale Mirc.gen.tr tarafından görsel olarak anlatılmıştır lütfen kaynak göstermeden yayınlamayınız.!

This entry was posted on Pazar, Mayıs 31st, 2009 at 05:10 and is filed under Hazir Kodlar, IRC Makaleleri, Mirc Script Dersleri. You can follow any responses to this entry through the RSS 2.0 feed. You can leave a response, or trackback from your own site.

Giriş

Kategoriler

Sayfalar

Son Yazılar

Son Yorumlar